_{Alexandru Ionascu - AAC 2021
[Project Video]}

This project aims to create a system that notifies owner on his smartphone about a possible flood via push notifications. This will be achieved by measuring the distance from the floor to the ultrasonic sound sensor and if it's less than 2 centimeters, it will trigger a push notification by sending a POST request to the Pushover API.

The system consists in two main components: ESP32 board and HC-SR04 ultrasonic sensor.

• ESP32 is the main component and has the following roles:
  • to establish Wi-Fi connection that will allow to perform HTTP requests;
  • to send POST requests to the Pushover API to trigger push notifications;
  • to determine the distance to the floor based on received input from the ultrasonic sensor;
    
• HC-SR04 serves as the proximity sensor and has the following roles:
  
  • to provide informations about the distance to the floor;

The hardware has two main components:

• ESP32 Board
  • The ESP32 Board controls the entire system. It establishes the Wi-Fi connection, it measures the water level based on the input received form the ultrasonic sensor and performs HTTP POST request if floor level is closer than 2cm.

• HC-SR04 Ultrasonic Sensor
  • The module is used to measure the distance from the sensor to the floor which helps the ESP32 Board to decide if the floor level has raised depending on the water lever.
  • The concept behind the ultrasonic sensor is the following: by sending out a sound wave at a frequency above the range of human hearing, the transducer of the sensor acts as a microphone to receive and send the ultrasonic sound. The sensor determines the distance to a target by measuring time lapses between the sending and receiving of the ultrasonic pulse. It sends an ultrasonic pulse out at 40kHz which travels through the air and if there is an obstacle or object, it will bounce back to the sensor. By calculating the travel time and the speed of sound, the distance can be calculated.
  • The trigger signal is linked to the digital GPIO 5, the echo signal is linked to the GPIO 18, the VCC signal is linked to 5V and the ground signal is linked to GND.

The diagram associated with the hardware will look like this:

The code consists of two main functions: setup and loop. In the setup function, we will set the echo and trigger pins and we will connect to the local Wi-Fi network to perform further HTTP requests. Once the connection is established, in the loop function, we will measure the distance to the floor in centimeters by sending ulstrasonic impulses and if this is less than 2 centimeters, we will perform a POST request to the Pushover API. There will also be a 2s delay between requests to make avoid unnecessary push notifications.

The source code is listed below:

main.cc

#include <WiFi.h>
#include <HTTPClient.h>
 
#define SOUND_SPEED 0.034
#define CM_TO_INCH 0.393701
#define DISTANCE 2.0
 
#define PUSHOVER_URL "https://api.pushover.net/1/messages.json"
 
const int trigPin = 5;
const int echoPin = 18;
 
const char* ssid = "********";
const char* password = "********";
 
long duration;
float distanceCm;
 
void setup() {
    Serial.begin(115200);
 
    pinMode(trigPin, OUTPUT);
    pinMode(echoPin, INPUT);
 
    WiFi.begin(ssid, password);
 
    while (WiFi.status() != WL_CONNECTED) {
        delay(1000);
        Serial.println("Connecting to WiFi...");
    }
 
    Serial.println("Connected to the WiFi network");
}
 
void loop() {
    if ((WiFi.status() == WL_CONNECTED)) {
        digitalWrite(trigPin, LOW);
        delayMicroseconds(2);
 
        digitalWrite(trigPin, HIGH);
        delayMicroseconds(10);
        digitalWrite(trigPin, LOW);
 
        // Reads the echoPin, returns the sound wave travel time in microseconds
        duration = pulseIn(echoPin, HIGH);
 
        // Calculate the distance
        distanceCm = (duration * SOUND_SPEED) / 2;
 
        if (distanceCm < DISTANCE) {
            HTTPClient http;
 
            http.begin(PUSHOVER_URL);
            http.addHeader("Content-Type", "application/x-www-form-urlencoded");
 
            String form = "device=device&user=********&title=IoT - ESP32&message=Flood!!&token=********";
 
            int httpCode = http.POST(form);
 
            if (httpCode > 0) {
                String payload = http.getString();
 
                Serial.println(httpCode);
                Serial.println(payload);
            }
 
            http.end();
 
            delay(2000);
        } else {
            Serial.println("Error on HTTP request");
        }
    }
}

This project had some initial issues with getting the source code up on the board, but for some reasons it got fixed once we switched from MacOS to Linux.

Another problem would be testing this application in a real life case scenario because it won't be that easy to simulate flood home.

ESP32: Connecting to a WiFi network
ESP32: HTTP POST Requests
ESP32 with HC-SR04 Ultrasonic Sensor with Arduino IDE